Files
FemLite/tests/unit/test_material_j2.f90
T
shenw be02684827
FemLite CI / build-test (push) Has been cancelled
Release FemLite 0.3.0
2026-06-23 19:28:44 +08:00

464 lines
16 KiB
Fortran

program test_material_j2
use fem_precision
use fem_error
use fem_database
use fem_material_j2
implicit none
real(rk), parameter :: E_TEST = 2.10e5_rk
real(rk), parameter :: NU_TEST = 0.30_rk
real(rk), parameter :: YIELD_TEST = 200.0_rk
real(rk), parameter :: HARD_TEST = 2.00e4_rk
real(rk), parameter :: TOL = 1.0e-8_rk
integer :: ierr
real(rk) :: deps(NSTRESS)
real(rk) :: stress_old(NSTRESS)
real(rk) :: stress_new(NSTRESS)
real(rk) :: state_old(NSTATEV_MAX)
real(rk) :: state_new(NSTATEV_MAX)
real(rk) :: lateral_deps
real(rk) :: eps_total
real(rk) :: eqps_expected
real(rk) :: sigma_expected
real(rk) :: stress_low_rate
real(rk) :: temp_expected
real(rk) :: spin_inc(3)
real(rk) :: dmat(NSTRESS,NSTRESS)
call setup_elastic(ierr)
if (ierr .ne. FEM_SUCCESS) stop 1
deps = ZERO
deps(1) = 1.0e-3_rk
deps(2) = -NU_TEST * deps(1)
deps(3) = -NU_TEST * deps(1)
stress_old = ZERO
state_old = ZERO
call material_update_small_strain(1, deps, state_old, stress_old, &
stress_new, state_new, ierr)
if (ierr .ne. FEM_SUCCESS) stop 2
if (abs(stress_new(1) - E_TEST * deps(1)) .gt. TOL * E_TEST * deps(1)) stop 3
if (abs(stress_new(2)) .gt. TOL * E_TEST * deps(1)) stop 4
if (abs(stress_new(3)) .gt. TOL * E_TEST * deps(1)) stop 5
if (maxval(abs(stress_new(4:6))) .gt. TOL * E_TEST * deps(1)) stop 6
if (abs(state_new(1)) .gt. TOL) stop 7
deps = ZERO
stress_old = ZERO
stress_old(1) = 100.0_rk
state_old = ZERO
spin_inc = ZERO
spin_inc(1) = -1.0e-2_rk
call material_update_small_strain_dt(1, ZERO, deps, state_old, stress_old, &
stress_new, state_new, ierr, spin_inc)
if (ierr .ne. FEM_SUCCESS) stop 8
if (abs(stress_new(1) - 100.0_rk) .gt. TOL * 100.0_rk) stop 9
if (abs(stress_new(4) - 1.0_rk) .gt. TOL) stop 100
call setup_j2_linear(ierr)
if (ierr .ne. FEM_SUCCESS) stop 10
stress_old = ZERO
state_old = ZERO
call uniaxial_stress_update(5.0e-4_rk, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 11
if (abs(stress_new(1) - E_TEST * 5.0e-4_rk) .gt. &
TOL * E_TEST * 5.0e-4_rk) stop 12
if (abs(stress_new(2)) .gt. TOL * E_TEST * 5.0e-4_rk) stop 13
if (abs(stress_new(3)) .gt. TOL * E_TEST * 5.0e-4_rk) stop 14
if (abs(state_new(1)) .gt. TOL) stop 15
stress_old = ZERO
state_old = ZERO
eps_total = 5.0e-3_rk
call uniaxial_stress_update(eps_total, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 20
eqps_expected = (E_TEST * eps_total - YIELD_TEST) / (E_TEST + HARD_TEST)
sigma_expected = YIELD_TEST + HARD_TEST * eqps_expected
if (abs(stress_new(1) - sigma_expected) .gt. TOL * sigma_expected) stop 21
if (abs(stress_new(2)) .gt. TOL * sigma_expected) stop 22
if (abs(stress_new(3)) .gt. TOL * sigma_expected) stop 23
if (abs(state_new(1) - eqps_expected) .gt. TOL * eqps_expected) stop 24
call material_tangent_small_strain(1, stress_new, state_new, dmat, ierr)
if (ierr .ne. FEM_SUCCESS) stop 25
if (dmat(1,1) .le. ZERO .or. dmat(1,1) .ge. E_TEST) stop 26
if (abs(dmat(1,2) - dmat(2,1)) .gt. TOL * E_TEST) stop 27
stress_old = stress_new
state_old = state_new
call uniaxial_stress_update(-1.0e-3_rk, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 30
sigma_expected = sigma_expected - E_TEST * 1.0e-3_rk
if (abs(stress_new(1) - sigma_expected) .gt. TOL * max(ONE, abs(sigma_expected))) stop 31
if (abs(stress_new(2)) .gt. TOL * YIELD_TEST) stop 32
if (abs(stress_new(3)) .gt. TOL * YIELD_TEST) stop 33
if (abs(state_new(1) - eqps_expected) .gt. TOL * eqps_expected) stop 34
call setup_jc_rate(ierr)
if (ierr .ne. FEM_SUCCESS) stop 50
stress_old = ZERO
state_old = ZERO
eps_total = 5.0e-3_rk
call uniaxial_stress_update_dt(eps_total, 10.0_rk, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 51
stress_low_rate = stress_new(1)
sigma_expected = YIELD_TEST
if (abs(stress_new(1) - sigma_expected) .gt. TOL * sigma_expected) stop 52
if (state_new(20) .gt. ONE) stop 53
call setup_jc_rate(ierr)
if (ierr .ne. FEM_SUCCESS) stop 54
stress_old = ZERO
state_old = ZERO
call uniaxial_stress_update_dt(eps_total, 1.0e-3_rk, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 55
call solve_jc_rate_uniaxial_expected(eps_total, 1.0e-3_rk, &
sigma_expected, eqps_expected, ierr)
if (ierr .ne. FEM_SUCCESS) stop 56
if (stress_new(1) .le. stress_low_rate) stop 57
if (abs(stress_new(1) - sigma_expected) .gt. TOL * sigma_expected) stop 58
if (abs(state_new(1) - eqps_expected) .gt. TOL * eqps_expected) stop 59
if (state_new(20) .le. ONE) stop 60
call setup_jc_temperature(ierr)
if (ierr .ne. FEM_SUCCESS) stop 70
stress_old = ZERO
state_old = ZERO
state_old(3) = 800.0_rk
eps_total = 5.0e-3_rk
call uniaxial_stress_update(eps_total, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 71
sigma_expected = YIELD_TEST * 0.5_rk
eqps_expected = (E_TEST * eps_total - sigma_expected) / E_TEST
if (abs(stress_new(1) - sigma_expected) .gt. TOL * sigma_expected) stop 72
if (abs(state_new(1) - eqps_expected) .gt. TOL * eqps_expected) stop 73
if (abs(state_new(3) - 800.0_rk) .gt. TOL * 800.0_rk) stop 74
call setup_jc_heat(ierr)
if (ierr .ne. FEM_SUCCESS) stop 80
stress_old = ZERO
state_old = ZERO
eps_total = 5.0e-3_rk
call uniaxial_stress_update(eps_total, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 81
sigma_expected = YIELD_TEST
eqps_expected = (E_TEST * eps_total - sigma_expected) / E_TEST
temp_expected = 300.0_rk + 0.9_rk * sigma_expected * eqps_expected / 100.0_rk
if (abs(stress_new(1) - sigma_expected) .gt. TOL * sigma_expected) stop 82
if (abs(state_new(1) - eqps_expected) .gt. TOL * eqps_expected) stop 83
if (abs(state_new(3) - temp_expected) .gt. TOL * temp_expected) stop 84
call setup_jc_damage(ierr)
if (ierr .ne. FEM_SUCCESS) stop 90
stress_old = ZERO
state_old = ZERO
eps_total = 5.0e-3_rk
call uniaxial_stress_update(eps_total, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 91
sigma_expected = YIELD_TEST
eqps_expected = (E_TEST * eps_total - sigma_expected) / E_TEST
if (abs(state_new(2) - eqps_expected / 0.01_rk) .gt. &
TOL * eqps_expected / 0.01_rk) stop 92
if (abs(state_new(4)) .gt. TOL) stop 93
stress_old = stress_new
state_old = state_new
call uniaxial_stress_update(ZERO, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 94
if (abs(state_new(2) - state_old(2)) .gt. TOL * state_old(2)) stop 95
if (abs(state_new(22)) .gt. TOL) stop 96
mat_jc_d1(1) = 1.0e-4_rk
stress_old = ZERO
state_old = ZERO
call uniaxial_stress_update(eps_total, stress_old, state_old, &
stress_new, state_new, lateral_deps, ierr)
if (ierr .ne. FEM_SUCCESS) stop 97
if (state_new(2) .lt. ONE) stop 98
if (state_new(4) .lt. ONE) stop 99
call database_finalize(ierr)
if (ierr .ne. FEM_SUCCESS) stop 40
contains
subroutine setup_elastic(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 0, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'ELASTIC'
mat_plastic_model(1) = 'ELASTIC'
mat_density(1) = 7850.0_rk
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
ierr = FEM_SUCCESS
end subroutine setup_elastic
subroutine setup_j2_linear(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 2, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'J2_LINEAR'
mat_plastic_model(1) = 'J2'
mat_density(1) = 7850.0_rk
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
mat_yield0(1) = YIELD_TEST
mat_hardening_modulus(1) = HARD_TEST
mat_plastic_start(1) = 1
mat_plastic_count(1) = 2
mat_plastic_stress(1) = YIELD_TEST
mat_plastic_strain(1) = ZERO
mat_plastic_stress(2) = YIELD_TEST + HARD_TEST * 0.01_rk
mat_plastic_strain(2) = 0.01_rk
ierr = FEM_SUCCESS
end subroutine setup_j2_linear
subroutine setup_jc_rate(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 0, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'JC_RATE'
mat_plastic_model(1) = 'J2_JC'
mat_rate_model(1) = 'JOHNSON_COOK'
mat_density(1) = 7850.0_rk
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
mat_yield0(1) = YIELD_TEST
mat_jc_a(1) = YIELD_TEST
mat_jc_b(1) = ZERO
mat_jc_n(1) = ONE
mat_jc_c(1) = 0.05_rk
mat_jc_epsdot0(1) = ONE
ierr = FEM_SUCCESS
end subroutine setup_jc_rate
subroutine setup_jc_temperature(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 0, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'JC_TEMP'
mat_plastic_model(1) = 'J2_JC'
mat_temp_model(1) = 'JOHNSON_COOK'
mat_density(1) = 7850.0_rk
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
mat_yield0(1) = YIELD_TEST
mat_jc_a(1) = YIELD_TEST
mat_jc_b(1) = ZERO
mat_jc_n(1) = ONE
mat_jc_m(1) = ONE
mat_jc_troom(1) = 300.0_rk
mat_jc_tmelt(1) = 1300.0_rk
ierr = FEM_SUCCESS
end subroutine setup_jc_temperature
subroutine setup_jc_heat(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 0, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'JC_HEAT'
mat_plastic_model(1) = 'J2_JC'
mat_density(1) = ONE
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
mat_yield0(1) = YIELD_TEST
mat_jc_a(1) = YIELD_TEST
mat_jc_b(1) = ZERO
mat_jc_n(1) = ONE
mat_jc_troom(1) = 300.0_rk
mat_jc_chi(1) = 0.9_rk
mat_jc_cp(1) = 100.0_rk
ierr = FEM_SUCCESS
end subroutine setup_jc_heat
subroutine setup_jc_damage(ierr)
integer, intent(out) :: ierr
call database_allocate_model(1, 1, 0, 0, 0, 0, 1, 0, 0, &
0, 0, 0, 0, 0, ierr)
if (ierr .ne. FEM_SUCCESS) return
mat_name(1) = 'JC_DAMAGE'
mat_plastic_model(1) = 'J2_JC'
mat_failure_model(1) = 'JOHNSON_COOK'
mat_density(1) = 7850.0_rk
mat_e(1) = E_TEST
mat_nu(1) = NU_TEST
mat_yield0(1) = YIELD_TEST
mat_jc_a(1) = YIELD_TEST
mat_jc_b(1) = ZERO
mat_jc_n(1) = ONE
mat_jc_d1(1) = 0.01_rk
mat_jc_d2(1) = ZERO
mat_jc_d3(1) = ZERO
mat_jc_d4(1) = ZERO
mat_jc_d5(1) = ZERO
ierr = FEM_SUCCESS
end subroutine setup_jc_damage
subroutine uniaxial_stress_update(axial_deps, stress_in, state_in, &
stress_out, state_out, lateral_deps, ierr)
real(rk), intent(in) :: axial_deps
real(rk), intent(in) :: stress_in(NSTRESS)
real(rk), intent(in) :: state_in(NSTATEV_MAX)
real(rk), intent(out) :: stress_out(NSTRESS)
real(rk), intent(out) :: state_out(NSTATEV_MAX)
real(rk), intent(out) :: lateral_deps
integer, intent(out) :: ierr
call uniaxial_stress_update_dt(axial_deps, ZERO, stress_in, state_in, &
stress_out, state_out, lateral_deps, ierr)
end subroutine uniaxial_stress_update
subroutine uniaxial_stress_update_dt(axial_deps, dt, stress_in, state_in, &
stress_out, state_out, lateral_deps, ierr)
real(rk), intent(in) :: axial_deps
real(rk), intent(in) :: dt
real(rk), intent(in) :: stress_in(NSTRESS)
real(rk), intent(in) :: state_in(NSTATEV_MAX)
real(rk), intent(out) :: stress_out(NSTRESS)
real(rk), intent(out) :: state_out(NSTATEV_MAX)
real(rk), intent(out) :: lateral_deps
integer, intent(out) :: ierr
real(rk) :: deps_local(NSTRESS)
real(rk) :: stress_trial(NSTRESS)
real(rk) :: state_trial(NSTATEV_MAX)
real(rk) :: stress_pert(NSTRESS)
real(rk) :: state_pert(NSTATEV_MAX)
real(rk) :: lateral
real(rk) :: residual
real(rk) :: residual_pert
real(rk) :: tangent
real(rk) :: perturb
integer :: iter
lateral = -NU_TEST * axial_deps
perturb = max(1.0e-8_rk, abs(axial_deps) * 1.0e-6_rk)
do iter = 1, 30
call update_with_lateral(axial_deps, lateral, dt, stress_in, state_in, &
stress_trial, state_trial, ierr)
if (ierr .ne. FEM_SUCCESS) return
residual = HALF * (stress_trial(2) + stress_trial(3))
if (abs(residual) .le. 1.0e-9_rk * E_TEST) exit
call update_with_lateral(axial_deps, lateral + perturb, dt, stress_in, &
state_in, stress_pert, state_pert, ierr)
if (ierr .ne. FEM_SUCCESS) return
residual_pert = HALF * (stress_pert(2) + stress_pert(3))
tangent = (residual_pert - residual) / perturb
if (abs(tangent) .le. ZERO) then
call error_set(FEM_ERR_MATERIAL, 'uniaxial test found zero lateral tangent', ierr)
return
end if
lateral = lateral - residual / tangent
end do
deps_local = ZERO
deps_local(1) = axial_deps
deps_local(2) = lateral
deps_local(3) = lateral
call material_update_small_strain_dt(1, dt, deps_local, state_in, &
stress_in, stress_out, state_out, ierr)
if (ierr .ne. FEM_SUCCESS) return
lateral_deps = lateral
end subroutine uniaxial_stress_update_dt
subroutine update_with_lateral(axial_deps, lateral_deps, dt, stress_in, state_in, &
stress_out, state_out, ierr)
real(rk), intent(in) :: axial_deps
real(rk), intent(in) :: lateral_deps
real(rk), intent(in) :: dt
real(rk), intent(in) :: stress_in(NSTRESS)
real(rk), intent(in) :: state_in(NSTATEV_MAX)
real(rk), intent(out) :: stress_out(NSTRESS)
real(rk), intent(out) :: state_out(NSTATEV_MAX)
integer, intent(out) :: ierr
real(rk) :: deps_local(NSTRESS)
deps_local = ZERO
deps_local(1) = axial_deps
deps_local(2) = lateral_deps
deps_local(3) = lateral_deps
call material_update_small_strain_dt(1, dt, deps_local, state_in, &
stress_in, stress_out, state_out, ierr)
end subroutine update_with_lateral
subroutine solve_jc_rate_uniaxial_expected(total_strain, dt, sigma, eqps, ierr)
real(rk), intent(in) :: total_strain
real(rk), intent(in) :: dt
real(rk), intent(out) :: sigma
real(rk), intent(out) :: eqps
integer, intent(out) :: ierr
real(rk) :: residual
real(rk) :: tangent
real(rk) :: rate_factor
real(rk) :: drate
integer :: iter
eqps = max(ZERO, (E_TEST * total_strain - YIELD_TEST) / E_TEST)
do iter = 1, 30
if (eqps / dt .gt. ONE) then
rate_factor = ONE + 0.05_rk * log(eqps / dt)
drate = 0.05_rk / eqps
else
rate_factor = ONE
drate = ZERO
end if
residual = E_TEST * (total_strain - eqps) - YIELD_TEST * rate_factor
if (abs(residual) .le. TOL * YIELD_TEST) exit
tangent = -E_TEST - YIELD_TEST * drate
if (abs(tangent) .le. ZERO) then
call error_set(FEM_ERR_MATERIAL, 'failed to solve JC expected stress', ierr)
return
end if
eqps = eqps - residual / tangent
if (eqps .lt. ZERO) eqps = ZERO
end do
if (eqps / dt .gt. ONE) then
rate_factor = ONE + 0.05_rk * log(eqps / dt)
else
rate_factor = ONE
end if
sigma = YIELD_TEST * rate_factor
ierr = FEM_SUCCESS
end subroutine solve_jc_rate_uniaxial_expected
end program test_material_j2