Files
FemLite/tests/module/test_linear_solver_cg.f90
T
2026-06-22 21:00:21 +08:00

129 lines
3.5 KiB
Fortran

program test_linear_solver_cg
use fem_precision
use fem_error
use fem_sparse_csr
use fem_linear_solver_cg
implicit none
real(rk), parameter :: TOL = 1.0e-9_rk
call check_spd_solve()
call check_zero_rhs()
call check_nonconvergence()
contains
subroutine check_spd_solve()
type(csr_matrix) :: a
integer :: ierr
integer :: iter
real(rk) :: b(3)
real(rk) :: x(3)
real(rk) :: res_norm
call make_tridiagonal(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(1)
b = (/ ZERO, ZERO, 4.0_rk /)
x = ZERO
call linear_cg_solve(a, b, x, 20, 1.0e-12_rk, iter, res_norm, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(2)
if (iter .le. 0 .or. iter .gt. 3) call fail(3)
if (res_norm .gt. 1.0e-10_rk) call fail(4)
call check_close(x(1), ONE, 5)
call check_close(x(2), 2.0_rk, 6)
call check_close(x(3), 3.0_rk, 7)
call csr_free(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(8)
end subroutine check_spd_solve
subroutine check_zero_rhs()
type(csr_matrix) :: a
integer :: ierr
integer :: iter
real(rk) :: b(3)
real(rk) :: x(3)
real(rk) :: res_norm
call make_tridiagonal(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(20)
b = ZERO
x = ZERO
call linear_cg_solve(a, b, x, 20, 1.0e-12_rk, iter, res_norm, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(21)
if (iter .ne. 0) call fail(22)
if (res_norm .gt. ZERO) call fail(23)
if (maxval(abs(x)) .gt. ZERO) call fail(24)
call csr_free(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(25)
end subroutine check_zero_rhs
subroutine check_nonconvergence()
type(csr_matrix) :: a
integer :: ierr
integer :: iter
real(rk) :: b(3)
real(rk) :: x(3)
real(rk) :: res_norm
call make_tridiagonal(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(30)
b = (/ ZERO, ZERO, 4.0_rk /)
x = ZERO
call linear_cg_solve(a, b, x, 1, 1.0e-12_rk, iter, res_norm, ierr)
if (ierr .eq. FEM_SUCCESS) call fail(31)
if (iter .ne. 1) call fail(32)
if (res_norm .le. ZERO) call fail(33)
call csr_free(a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(34)
end subroutine check_nonconvergence
subroutine make_tridiagonal(a, ierr)
type(csr_matrix), intent(inout) :: a
integer, intent(out) :: ierr
integer :: row_ptr(4)
integer :: col_ind(7)
call csr_init(a)
row_ptr = (/ 1, 3, 6, 8 /)
col_ind = (/ 1, 2, 1, 2, 3, 2, 3 /)
call csr_create_pattern(a, 3, 3, row_ptr, col_ind, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 1, 1, 2.0_rk, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 1, 2, -ONE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 2, 1, -ONE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 2, 2, 2.0_rk, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 2, 3, -ONE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 3, 2, -ONE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call csr_add_value(a, 3, 3, 2.0_rk, ierr)
end subroutine make_tridiagonal
subroutine check_close(actual, expected, code)
real(rk), intent(in) :: actual
real(rk), intent(in) :: expected
integer, intent(in) :: code
if (abs(actual - expected) .gt. TOL) call fail(code)
end subroutine check_close
subroutine fail(code)
integer, intent(in) :: code
write(*,*) 'test_linear_solver_cg failed:', code
stop 1
end subroutine fail
end program test_linear_solver_cg