cmake_minimum_required(VERSION 3.22.1)
project(neslite_jni LANGUAGES C CXX)

set(CMAKE_CXX_STANDARD 20)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

set(NESLITE_COMMON_SOURCES
    rom_compatibility.cpp
    core_catalog.cpp
    video_conversion.cpp
    native_smoke.cpp
    session_rules.cpp
    audio_ring_buffer.cpp
    linear_resampler.cpp
    input_latency_metrics.cpp
    timing_metrics.cpp
    video_buffer.cpp
    video_viewport.cpp
    sha256.cpp
    safe_commit.cpp
    save_state.cpp
    save_policy.cpp
    save_package.cpp
)

function(neslite_enable_strict_warnings target)
    if(MSVC)
        target_compile_options(${target} PRIVATE /W4 /WX)
    else()
        target_compile_options(${target} PRIVATE -Wall -Wextra -Werror)
    endif()
endfunction()

if(ANDROID)
    include(cmake/fceumm.cmake)
    include(cmake/nestopia.cmake)
    include(cmake/oboe.cmake)
    add_library(neslite_jni SHARED
        core_api.cpp
        core_identity.cpp
        core_session.cpp
        audio_engine.cpp
        gl_renderer.cpp
        jni_bridge.cpp
        ${NESLITE_COMMON_SOURCES}
    )
    neslite_enable_strict_warnings(neslite_jni)
    target_include_directories(neslite_jni PRIVATE "${NESLITE_LIBRETRO_HEADERS_DIR}")
    target_include_directories(neslite_jni SYSTEM PRIVATE "${NESLITE_OBOE_DIR}/include")

    find_library(log-lib log)
    find_library(gles-lib GLESv2)
    target_link_libraries(neslite_jni PRIVATE fceumm_core oboe ${log-lib} ${gles-lib} dl)
    add_dependencies(neslite_jni neslite_nestopia)
else()
    enable_testing()
    add_executable(neslite_native_smoke_test
        tests/native_smoke_test.cpp
        ${NESLITE_COMMON_SOURCES}
    )
    target_include_directories(neslite_native_smoke_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
    neslite_enable_strict_warnings(neslite_native_smoke_test)
    add_test(NAME neslite_native_smoke_test COMMAND neslite_native_smoke_test)
    add_executable(neslite_core_selection_test tests/core_selection_test.cpp
        core_catalog.cpp video_conversion.cpp video_buffer.cpp save_package.cpp save_state.cpp sha256.cpp)
    target_include_directories(neslite_core_selection_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
    neslite_enable_strict_warnings(neslite_core_selection_test)
    add_test(NAME neslite_core_selection_test COMMAND neslite_core_selection_test)
    add_executable(neslite_rom_compatibility_test tests/rom_compatibility_test.cpp rom_compatibility.cpp)
    target_include_directories(neslite_rom_compatibility_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
    neslite_enable_strict_warnings(neslite_rom_compatibility_test)
    add_test(NAME neslite_rom_compatibility_test COMMAND neslite_rom_compatibility_test)
    add_executable(neslite_video_viewport_test tests/video_viewport_test.cpp video_buffer.cpp video_viewport.cpp)
    target_include_directories(neslite_video_viewport_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
    neslite_enable_strict_warnings(neslite_video_viewport_test)
    add_test(NAME neslite_video_viewport_test COMMAND neslite_video_viewport_test)
endif()
