Files
CCLite/FEMLite/examples/run_example_case.bat
T
2026-07-05 22:48:27 +08:00

58 lines
1.3 KiB
Batchfile

@echo off
setlocal
if "%~5"=="" goto usage
set "CASE_DIR=%~1"
set "CASE_NAME=%~2"
set "MODE=%~3"
set "INP_FILE=%~4"
set "OUT_INTERVAL=%~5"
set "ROOT_DIR=%CASE_DIR%..\.."
set "EXE=%ROOT_DIR%\cpu_release\bin\femlite.exe"
set "INP=%CASE_DIR%%INP_FILE%"
set "OUT_DIR=%CASE_DIR%results\auto_run"
echo FemLite %CASE_NAME%
echo.
if not exist "%INP%" (
echo Input file was not found: "%INP%"
goto fail
)
if not exist "%EXE%" (
echo femlite.exe was not found: "%EXE%"
goto fail
)
if not exist "%OUT_DIR%" mkdir "%OUT_DIR%"
del /Q "%OUT_DIR%\history.csv" 2>nul
del /Q "%OUT_DIR%\nodes_*.csv" 2>nul
del /Q "%OUT_DIR%\elements_*.csv" 2>nul
del /Q "%OUT_DIR%\reactions_*.csv" 2>nul
del /Q "%OUT_DIR%\contact_*.csv" 2>nul
del /Q "%OUT_DIR%\result_*.vtu" 2>nul
del /Q "%OUT_DIR%\results.pvd" 2>nul
del /Q "%OUT_DIR%\continuation_path.csv" 2>nul
echo Running FemLite...
"%EXE%" "%INP%" --output-dir "%OUT_DIR%" --output-interval %OUT_INTERVAL% %MODE%
if errorlevel 1 goto fail
echo.
echo Case completed successfully.
if not "%FEMLITE_NO_PAUSE%"=="1" pause
exit /b 0
:usage
echo Usage: run_example_case.bat CASE_DIR CASE_NAME MODE INP_FILE OUTPUT_INTERVAL
goto fail
:fail
echo.
echo Case failed.
if not "%FEMLITE_NO_PAUSE%"=="1" pause
exit /b 1