Files
FemLite/examples/run_example_case.bat
T
shenw 240d2728fa
FemLite CI / build-test (push) Has been cancelled
Complete V4.8 example acceptance and scripts
2026-06-25 10:29:03 +08:00

57 lines
1.2 KiB
Batchfile

@echo off
setlocal
if "%~5"=="" goto usage
set "CASE_DIR=%~1"
set "CASE_NAME=%~2"
set "MODE=%~3"
set "INP_FILE=%~4"
set "OUT_INTERVAL=%~5"
set "ROOT_DIR=%CASE_DIR%..\.."
set "EXE=%ROOT_DIR%\build-win-gcc-16\femlite.exe"
set "INP=%CASE_DIR%%INP_FILE%"
set "OUT_DIR=%CASE_DIR%results\auto_run"
echo FemLite %CASE_NAME%
echo.
if not exist "%INP%" (
echo Input file was not found: "%INP%"
goto fail
)
if not exist "%EXE%" (
echo femlite.exe was not found. Trying to build build-win-gcc-16...
cmake --build "%ROOT_DIR%\build-win-gcc-16" --config Release
if errorlevel 1 goto fail
)
if not exist "%OUT_DIR%" mkdir "%OUT_DIR%"
del /Q "%OUT_DIR%\history.csv" 2>nul
del /Q "%OUT_DIR%\nodes_*.csv" 2>nul
del /Q "%OUT_DIR%\elements_*.csv" 2>nul
del /Q "%OUT_DIR%\reactions_*.csv" 2>nul
del /Q "%OUT_DIR%\contact_*.csv" 2>nul
del /Q "%OUT_DIR%\result_*.vtk" 2>nul
echo Running FemLite...
"%EXE%" "%INP%" --output-dir "%OUT_DIR%" --output-interval %OUT_INTERVAL% %MODE%
if errorlevel 1 goto fail
echo.
echo Case completed successfully.
if not "%FEMLITE_NO_PAUSE%"=="1" pause
exit /b 0
:usage
echo Usage: run_example_case.bat CASE_DIR CASE_NAME MODE INP_FILE OUTPUT_INTERVAL
goto fail
:fail
echo.
echo Case failed.
if not "%FEMLITE_NO_PAUSE%"=="1" pause
exit /b 1