173 lines
5.4 KiB
Fortran
173 lines
5.4 KiB
Fortran
program test_buckling_support
|
|
use fem_precision
|
|
use fem_error
|
|
use fem_geometric_stiffness
|
|
use fem_modal_output
|
|
implicit none
|
|
|
|
real(rk), parameter :: TOL = 1.0e-10_rk
|
|
|
|
call check_truss_geometric()
|
|
call check_beam_column_geometric()
|
|
call check_axial_projection()
|
|
call check_modal_output()
|
|
call check_error_paths()
|
|
|
|
contains
|
|
|
|
subroutine check_truss_geometric()
|
|
real(rk) :: x1(3)
|
|
real(rk) :: x2(3)
|
|
real(rk) :: kg(6,6)
|
|
real(rk) :: projector(3,3)
|
|
real(rk) :: length
|
|
real(rk) :: rigid(6)
|
|
integer :: ierr
|
|
|
|
x1 = (/ ZERO, ZERO, ZERO /)
|
|
x2 = (/ 2.0_rk, ZERO, ZERO /)
|
|
call geom_truss3d_stiffness(x1, x2, 100.0_rk, kg, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(10)
|
|
call check_close(kg(1,1), ZERO, 11)
|
|
call check_close(kg(2,2), 50.0_rk, 12)
|
|
call check_close(kg(3,3), 50.0_rk, 13)
|
|
call check_close(kg(2,5), -50.0_rk, 14)
|
|
call check_close(kg(3,6), -50.0_rk, 15)
|
|
if (maxval(abs(kg - transpose(kg))) .gt. TOL) call fail(16)
|
|
|
|
rigid = (/ ONE, 2.0_rk, 3.0_rk, ONE, 2.0_rk, 3.0_rk /)
|
|
if (maxval(abs(matmul(kg, rigid))) .gt. TOL) call fail(17)
|
|
|
|
call geom_projector_transverse(x1, x2, projector, length, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(18)
|
|
call check_close(length, 2.0_rk, 19)
|
|
call check_close(projector(1,1), ZERO, 20)
|
|
call check_close(projector(2,2), ONE, 21)
|
|
call check_close(projector(3,3), ONE, 22)
|
|
end subroutine check_truss_geometric
|
|
|
|
subroutine check_beam_column_geometric()
|
|
real(rk) :: kg(4,4)
|
|
real(rk) :: length
|
|
real(rk) :: force
|
|
integer :: ierr
|
|
|
|
length = 3.0_rk
|
|
force = 90.0_rk
|
|
call geom_beam2d_column_stiffness(length, force, kg, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(40)
|
|
call check_close(kg(1,1), 36.0_rk * force / (30.0_rk * length), 41)
|
|
call check_close(kg(2,2), 4.0_rk * length * length * &
|
|
force / (30.0_rk * length), 42)
|
|
call check_close(kg(2,4), -length * length * &
|
|
force / (30.0_rk * length), 43)
|
|
if (maxval(abs(kg - transpose(kg))) .gt. TOL) call fail(44)
|
|
|
|
call geom_beam2d_column_stiffness(ZERO, force, kg, ierr)
|
|
if (ierr .eq. FEM_SUCCESS) call fail(45)
|
|
end subroutine check_beam_column_geometric
|
|
|
|
subroutine check_axial_projection()
|
|
real(rk) :: stress(NSTRESS)
|
|
real(rk) :: direction(3)
|
|
real(rk) :: force
|
|
integer :: ierr
|
|
|
|
stress = ZERO
|
|
stress(1) = 10.0_rk
|
|
stress(2) = 20.0_rk
|
|
stress(3) = 30.0_rk
|
|
stress(4) = 2.0_rk
|
|
direction = (/ ONE, ZERO, ZERO /)
|
|
|
|
call geom_effective_axial_force(stress, direction, 4.0_rk, force, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(60)
|
|
call check_close(force, 40.0_rk, 61)
|
|
|
|
direction = (/ ONE, ONE, ZERO /)
|
|
call geom_effective_axial_force(stress, direction, 2.0_rk, force, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(62)
|
|
call check_close(force, 34.0_rk, 63)
|
|
end subroutine check_axial_projection
|
|
|
|
subroutine check_modal_output()
|
|
character(len=*), parameter :: OUT_FILE = 'test_modal_output_tmp.csv'
|
|
real(rk) :: modes(3,2)
|
|
real(rk) :: eval(2)
|
|
real(rk) :: residuals(2)
|
|
real(rk) :: first_value
|
|
real(rk) :: last_value
|
|
real(rk) :: max_residual
|
|
real(rk) :: max_component
|
|
integer :: ierr
|
|
logical :: exists
|
|
|
|
modes(:,1) = (/ 0.5_rk, -2.0_rk, ONE /)
|
|
modes(:,2) = (/ -3.0_rk, 0.25_rk, 1.5_rk /)
|
|
eval = (/ 4.0_rk, 9.0_rk /)
|
|
residuals = (/ 1.0e-12_rk, 2.0e-12_rk /)
|
|
|
|
call modal_summary(3, 2, eval, residuals, modes, first_value, &
|
|
last_value, max_residual, max_component, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(80)
|
|
call check_close(first_value, 4.0_rk, 81)
|
|
call check_close(last_value, 9.0_rk, 82)
|
|
call check_close(max_residual, 2.0e-12_rk, 83)
|
|
call check_close(max_component, 3.0_rk, 84)
|
|
|
|
call modal_scale_to_max(3, 2, modes, 10.0_rk, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(85)
|
|
call check_close(maxval(abs(modes(:,1))), 10.0_rk, 86)
|
|
call check_close(maxval(abs(modes(:,2))), 10.0_rk, 87)
|
|
|
|
call modal_write_csv(OUT_FILE, 3, 2, eval, residuals, modes, ierr)
|
|
if (ierr .ne. FEM_SUCCESS) call fail(88)
|
|
inquire(file=OUT_FILE, exist=exists)
|
|
if (.not. exists) call fail(89)
|
|
call delete_file(OUT_FILE)
|
|
end subroutine check_modal_output
|
|
|
|
subroutine check_error_paths()
|
|
real(rk) :: x1(3)
|
|
real(rk) :: x2(3)
|
|
real(rk) :: kg(6,6)
|
|
real(rk) :: modes(2,1)
|
|
integer :: ierr
|
|
|
|
x1 = ZERO
|
|
x2 = ZERO
|
|
call geom_truss3d_stiffness(x1, x2, ONE, kg, ierr)
|
|
if (ierr .eq. FEM_SUCCESS) call fail(100)
|
|
|
|
modes = ZERO
|
|
call modal_scale_to_max(2, 1, modes, ONE, ierr)
|
|
if (ierr .eq. FEM_SUCCESS) call fail(101)
|
|
end subroutine check_error_paths
|
|
|
|
subroutine delete_file(filename)
|
|
character(len=*), intent(in) :: filename
|
|
integer :: unit_id
|
|
integer :: ios
|
|
|
|
unit_id = 93
|
|
open(unit=unit_id, file=filename, status='old', action='read', iostat=ios)
|
|
if (ios .eq. 0) close(unit_id, status='delete')
|
|
end subroutine delete_file
|
|
|
|
subroutine check_close(actual, expected, code)
|
|
real(rk), intent(in) :: actual
|
|
real(rk), intent(in) :: expected
|
|
integer, intent(in) :: code
|
|
|
|
if (abs(actual - expected) .gt. TOL * max(ONE, abs(expected))) call fail(code)
|
|
end subroutine check_close
|
|
|
|
subroutine fail(code)
|
|
integer, intent(in) :: code
|
|
|
|
write(*,*) 'test_buckling_support failed:', code
|
|
stop 1
|
|
end subroutine fail
|
|
|
|
end program test_buckling_support
|