Files
FemLite/tests/module/test_restart.f90
T
2026-06-22 23:49:30 +08:00

152 lines
4.2 KiB
Fortran

program test_restart
use fem_precision
use fem_error
use fem_api
implicit none
real(rk), parameter :: DT_TEST = 1.0e-8_rk
character(len=*), parameter :: RESTART_FILE = &
'build-wsl-debug/restart_check.frs'
integer :: ierr
integer :: ref_step
integer :: rst_step
real(rk) :: ref_time
real(rk) :: rst_time
real(rk) :: ref_u(NDIM)
real(rk) :: ref_v(NDIM)
real(rk) :: ref_a(NDIM)
real(rk) :: rst_u(NDIM)
real(rk) :: rst_v(NDIM)
real(rk) :: rst_a(NDIM)
call fem_initialize(ierr)
if (ierr .ne. FEM_SUCCESS) call fail(1)
call run_continuous(ref_step, ref_time, ref_u, ref_v, ref_a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(2)
call run_restarted(rst_step, rst_time, rst_u, rst_v, rst_a, ierr)
if (ierr .ne. FEM_SUCCESS) call fail(3)
if (ref_step .ne. 3) call fail(4)
if (rst_step .ne. ref_step) call fail(5)
call check_close(rst_time, ref_time, 6)
call check_vector(rst_u, ref_u, 7)
call check_vector(rst_v, ref_v, 8)
call check_vector(rst_a, ref_a, 9)
call fem_finalize(ierr)
if (ierr .ne. FEM_SUCCESS) call fail(10)
contains
subroutine run_continuous(step, time, disp, vel, acc, ierr)
integer, intent(out) :: step
real(rk), intent(out) :: time
real(rk), intent(out) :: disp(NDIM)
real(rk), intent(out) :: vel(NDIM)
real(rk), intent(out) :: acc(NDIM)
integer, intent(out) :: ierr
call prepare_model(ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_get_current_time(time, step, ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_get_node_kinematics(2, disp, vel, acc, ierr)
end subroutine run_continuous
subroutine run_restarted(step, time, disp, vel, acc, ierr)
integer, intent(out) :: step
real(rk), intent(out) :: time
real(rk), intent(out) :: disp(NDIM)
real(rk), intent(out) :: vel(NDIM)
real(rk), intent(out) :: acc(NDIM)
integer, intent(out) :: ierr
call prepare_model(ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_write_restart(RESTART_FILE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call prepare_model(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_read_restart(RESTART_FILE, ierr)
if (ierr .ne. FEM_SUCCESS) return
call loaded_step(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_get_current_time(time, step, ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_get_node_kinematics(2, disp, vel, acc, ierr)
end subroutine run_restarted
subroutine prepare_model(ierr)
integer, intent(out) :: ierr
call fem_read_inp('examples/c3d4_one_element.inp', ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_build_model(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_compute_lumped_mass(ierr)
end subroutine prepare_model
subroutine loaded_step(ierr)
integer, intent(out) :: ierr
real(rk) :: force(NDIM)
force = ZERO
force(1) = 5.0_rk
force(2) = 1.0_rk
force(3) = -2.0_rk
call fem_clear_sph_forces(ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_apply_sph_nodal_force(2, force, ierr)
if (ierr .ne. FEM_SUCCESS) return
call fem_advance_explicit(DT_TEST, ierr)
end subroutine loaded_step
subroutine check_vector(actual, expected, code)
real(rk), intent(in) :: actual(NDIM)
real(rk), intent(in) :: expected(NDIM)
integer, intent(in) :: code
integer :: idir
do idir = 1, NDIM
call check_close(actual(idir), expected(idir), code)
end do
end subroutine check_vector
subroutine check_close(actual, expected, code)
real(rk), intent(in) :: actual
real(rk), intent(in) :: expected
integer, intent(in) :: code
real(rk) :: scale
scale = max(ONE, abs(expected))
if (abs(actual - expected) .gt. 1.0e-8_rk * scale) call fail(code)
end subroutine check_close
subroutine fail(code)
integer, intent(in) :: code
write(*,*) 'test_restart failed:', code
stop 1
end subroutine fail
end program test_restart